# Contributor: Paul C. <paulr2787@gmail.com>

_realname=psycopg2
pkgbase=mingw-w64-python-${_realname}
#pkgname=("${MINGW_PACKAGE_PREFIX}-python2-${_realname}" "${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
pkgname=("${MINGW_PACKAGE_PREFIX}-python3-${_realname}")
pkgver=2.7.4
pkgrel=3.1
pkgdesc="Python bindings for postgresql"
arch=('any')
groups=('gramps_fixed')
license=('BSD')
url="http://initd.org/psycopg/"
makedepends=("${MINGW_PACKAGE_PREFIX}-python3"
             "${MINGW_PACKAGE_PREFIX}-postgresql")
options=('staticlibs' 'strip' '!debug')
source=("http://initd.org/psycopg/tarballs/PSYCOPG-2-7/${_realname}-${pkgver}.tar.gz"
        psycopg2.patch)
sha256sums=('8bf51191d60f6987482ef0cfe8511bbf4877a5aa7f313d7b488b53189cf26209'
            '08006eff9e298f3c296f3f9a4ecfe63dcc15efae4699c89246ff951aab4a78b7')
prepare() {
  plain "Patching setup files ..."
  cd ${_realname}-${pkgver}
  patch -Np1 -i ${srcdir}/psycopg2.patch
  cd ..

  cd "${srcdir}"
  rm -Rf build-${CARCH}
  cp -r ${_realname}-${pkgver} build-${CARCH}
}

build() {
  # Build python 3 module
  cd "${srcdir}/build-${CARCH}"
  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=;--install-purelib=;--install-data=" \
  ${MINGW_PREFIX}/bin/python3 setup.py build
}

package_python3-psycopg2() {
  depends=("${MINGW_PACKAGE_PREFIX}-python3"
           "${MINGW_PACKAGE_PREFIX}-postgresql")

  cd "${srcdir}/build-${CARCH}"
  MSYS2_ARG_CONV_EXCL="--prefix=;--install-scripts=;--install-platlib=;--install-purelib=;--install-data=" \
  ${MINGW_PREFIX}/bin/python3 setup.py install --prefix=${MINGW_PREFIX#\/} --root="${pkgdir}" --optimize=1 --skip-build
}

package_mingw-w64-i686-python3-psycopg2() {
  package_python3-${_realname}
}

package_mingw-w64-x86_64-python3-psycopg2() {
  package_python3-${_realname}
}
